函数SelectRow详细解析(数据窗口数据多选时用)

ehxz

免费乐捐，感谢支持

函数作用：选中或者取消选中数据窗口、DataStore中的一行或者所有行数据。该函数的执行不会改变当前数据行。也就是说，如果第2行是当前数据行，执行完该函数，比如dw_1.SelectRow(5)，第2行仍然是当前数据行。
函数语法：integer dwcontrol.SelectRow ( long row, boolean select )
ldwcontrol：数据窗口、DataStore或者子数据窗口。
lrow：long类型，要选中或者取消选中的数据行行号。如果该参数为0，表示对所有的数据行进行操作。
lselect：Boolean类型，取值为True表示要选中指定的数据行（不管在执行函数之前是否是选中的）；取值为False表示要取消选中指定的数据行（不管执行函数之前是否没有选中）。
返 回 值：函数执行成功返回1，执行错误返回-1，任何参数为空则返回Null。
代码实例：
例1：数据窗口中多行选中程序。
首先定义窗口实例变量：
long il_LastSelectedRow = 1
然后开始编写多行选中程序。程序算法描述如下：
1）、如果按下了Control键
如果是在选中行上，取消该行
   否则，选中该行
记录当前到窗口实例变量中
2）、如果按下了Shift键
取消所有选中行
选中上次点击行和当前行之间的所有数据行
记录当前到窗口实例变量中
3）、如果没有按键
 如果点击行为选中行，不执行任何操作
 否则，取消所有选中行，选中当前行
 记录当前到窗口实例变量中
比如，我们在窗口dw_1的Clicked事件中编写该脚本，程序如下：
long ll_Start
long ll_End
long ll_index

if Row < 1 then return

if KeyDown(KeyControl!) then
 if This.IsSelected(Row) then
   This.SelectRow(Row,False)
 else
   This.SelectRow(Row,True)
 end if
elseif KeyDown(KeyShift!) then
 if Row < il_LastSelectedRow then
   ll_Start = Row
   ll_End = il_LastSelectedRow
 else
   ll_Start = il_LastSelectedRow
   ll_End = Row
 end if

 This.SelectRow(0,False)
 For ll_index = ll_Start to ll_End
   This.SelectRow(ll_index,True)
 next
else
 if Not This.IsSelected(Row) then
   This.SelectRow(0,False)
   This.SelectRow(Row,True)
 end if
end if

il_LastSelectedRow = Row